home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / C64 / A-Monthly Disks / (c)ab.d64 / library index.c (.txt) < prev    next >
Commodore BASIC  |  2007-02-04  |  13KB  |  368 lines
  1. 10 REM  *******************************
  2. 20 REM  *    LIBRARY INDEX PROGRAM    *
  3. 30 REM  *                             *
  4. 40 REM  *        COMMODORE 64         *
  5. 50 REM  *     (WITH DISK DRIVE)       *
  6. 60 REM  *                             *
  7. 70 REM  * BRIAN SMITHER       3APR85  *
  8. 80 REM  * SACRAMENTO COMMODORE        *
  9. 90 REM  * COMPUTER CLUB               *
  10. 100 REM * P.O. BOX 13393              *
  11. 110 REM * SACRAMENTO, CA. 95813-3393  *
  12. 120 REM * (916) 344-5149              *
  13. 130 REM *                             *
  14. 140 REM *       ADAPTED FROM:         *
  15. 150 REM *                             *
  16. 160 REM *   MAGAZINE INDEX PROGRAM    *
  17. 170 REM *                             *
  18. 180 REM * DON WHITE                   *
  19. 190 REM * 47 ARIEL COURT              *
  20. 200 REM * NEPEAN, ONTARIO K2H 8J1     *
  21. 210 REM * (613) 829-2082              *
  22. 220 REM *******************************
  23. 230 A=144:DIM PB$(A),PN$(A),PC$(A),PE$(A),PM$(A),PS$(A),PI$(A),M$(80)
  24. 240 DEF FN CAT(F)=20*(F-133)+70*((F-133)>3):PLOT=65520:XREG=781:YREG=782
  25. 310 M$(1)="MAIL LIST      ": M$(41)="USER DEFINED  1"
  26. 320 M$(2)="WORD PROCESSOR ": M$(42)="USER DEFINED  2"
  27. 330 M$(3)="DATA BASE      ": M$(43)="USER DEFINED  3"
  28. 340 M$(4)="SPREADSHEET    ": M$(44)="USER DEFINED  4"
  29. 350 M$(5)="TELECOMMUNICATE": M$(45)="USER DEFINED  5"
  30. 360 M$(6)="GAME:SHOOTOUT  ": M$(46)="USER DEFINED  6"
  31. 370 M$(7)="GAME:MAZE      ": M$(47)="USER DEFINED  7"
  32. 380 M$(8)="GAME:ADVENTURE ": M$(48)="USER DEFINED  8"
  33. 390 M$(9)="GAME:EDUCATION ": M$(49)="USER DEFINED  9"
  34. 400 M$(10)="GAME:GRAB IT   ":M$(50)="USER DEFINED 10"
  35. 410 M$(11)="COMP. AID DESGN":M$(51)="USER DEFINED 11"
  36. 420 M$(12)="MUSIC SYNTHESYS":M$(52)="USER DEFINED 12"
  37. 430 M$(13)="SPRITE EDITOR  ":M$(53)="USER DEFINED 13"
  38. 440 M$(14)="HI-RES EDITOR  ":M$(54)="USER DEFINED 14"
  39. 450 M$(15)="CUST. CHAR'S ED":M$(55)="USER DEFINED 15"
  40. 460 M$(16)="HI-RES DUMPS   ":M$(56)="USER DEFINED 16"
  41. 470 M$(17)="PRE-DONE FORMS ":M$(57)="USER DEFINED 17"
  42. 480 M$(18)="PRINTER GRAPHS ":M$(58)="USER DEFINED 18"
  43. 490 M$(19)="USER CHRS PRNTR":M$(59)="USER DEFINED 19"
  44. 500 M$(20)="PRESET FORMAT  ":M$(60)="USER DEFINED 20"
  45. 510 M$(21)="MATH ED        ":M$(61)="USER DEFINED 21"
  46. 520 M$(22)="ENGLISH ED     ":M$(62)="USER DEFINED 22"
  47. 530 M$(23)="SCIENCE ED     ":M$(63)="USER DEFINED 23"
  48. 540 M$(24)="TECHNOLOGY ED  ":M$(64)="USER DEFINED 24"
  49. 550 M$(25)="BUSINESS ED    ":M$(65)="USER DEFINED 25"
  50. 560 M$(26)="PROGRAMMING ED ":M$(66)="USER DEFINED 26"
  51. 570 M$(27)="MACH. LANG. ED ":M$(67)="USER DEFINED 27"
  52. 580 M$(28)="GRAPHICS ED    ":M$(68)="USER DEFINED 28"
  53. 590 M$(29)="SOUND ED       ":M$(69)="USER DEFINED 29"
  54. 600 M$(30)="FOREIGN LANG'S ":M$(70)="USER DEFINED 30"
  55. 610 M$(31)="OTHER COMP LANG":M$(71)="USER DEFINED 31"
  56. 620 M$(32)="M.L. ASSEMBLER ":M$(72)="USER DEFINED 32"
  57. 630 M$(33)="COMPILER       ":M$(73)="USER DEFINED 33"
  58. 640 M$(34)="COMPUTER UTLITY":M$(74)="USER DEFINED 34"
  59. 650 M$(35)="DISK AIDS      ":M$(75)="USER DEFINED 35"
  60. 660 M$(36)="DISK UTILITIES ":M$(76)="USER DEFINED 36"
  61. 670 M$(37)="PRGM UTILITIES ":M$(77)="USER DEFINED 37"
  62. 680 M$(38)="PRGM AIDS      ":M$(78)="USER DEFINED 38"
  63. 690 M$(39)="MUSIC DEMOS    ":M$(79)="USER DEFINED 39"
  64. 700 M$(40)="GRAPHIC DEMOS  ":M$(80)="USER DEFINED 40"
  65. 710 OPEN15,8,15:POKE53280,0:POKE53281,0
  66. 750 PRINT"[147]"TAB(9)"[158]***  LIBRARY INDEX [146] ***"
  67. 820 PRINT""TAB(9)"1.[158]  INSTRUCTIONS"
  68. 870 PRINTTAB(9)"2.[158]  ADD/CREATE FILES"
  69. 910 PRINTTAB(9)"3.[158]  VIEW FILES"
  70. 950 PRINTTAB(9)"4.[158]  HARDCOPY FROM FILES"
  71. 990 PRINTTAB(9)"5.[158]  END"
  72. 1070 PRINTTAB(12)"ENTER CHOICE (1-5)"
  73. 1100 GETZZ$:ZZ=VAL(ZZ$)
  74. 1105 IFZZ<1ORZZ>5THEN1100
  75. 1110 ONZZGOTO1130,1400,6255,8220,12000
  76. 1130 PRINT"[147]"TAB(8)"[158]***  INSTRUCTIONS [146] ***"
  77. 1230 PRINT"[155]LIBRARY INDEX ALLOWS YOU TO SORT YOUR"
  78. 1240 PRINT"SOFTWARE LIBRARY TITLES BY CATEGORY."
  79. 1250 PRINT"NAMES OF CATEGORIES ARE FLEXIBLE."
  80. 1260 PRINT"LIST LINES 310-700 FOR THE NAMES."
  81. 1270 PRINT"BECAUSE YOU HAVE ELECTED TO READ THESE"
  82. 1280 PRINT"INSTRUCTIONS, AN INSTRUCTIONAL PAGE"
  83. 1290 PRINT"WILL BE DISPLAYED AS EACH FUNCTION IS"
  84. 1310 PRINT"ENTERED. TO BYPASS THESE PAGES, RESTART"
  85. 1320 PRINT"LIBRARY INDEX AVOIDING OPTION ONE."
  86. 1325 PRINT"LIBRARY INDEX IS MEANT TO BE USED TO"
  87. 1330 PRINT"FIND A PROGRAM WHEN THE APPLICATION IS"
  88. 1335 PRINT"KNOWN."
  89. 1360 PRINT"   PRESS ANY KEY."
  90. 1370 GETZZ$:IFZZ$=""THEN1370
  91. 1380 FL=1:GOTO750
  92. 1400 IFFL<>1THEN1720
  93. 1410 PRINT"[147]"TAB(8)"[158]***  INSTRUCTIONS [146] ***"
  94. 1500 PRINT"[155]ALL DISK MAINTENENCE IS ON DRIVE ZERO,"
  95. 1510 PRINT"DEVICE EIGHT. THE SOURCE DISK WILL ONLY"
  96. 1530 PRINT"NEED BE IN THE DRIVE ONCE AND ONLY IN"
  97. 1540 PRINT"THIS FUNCTION. PERTINENT INFORMATION IS"
  98. 1560 PRINT"READ FROM THE DISK AND WILL THEN BE"
  99. 1570 PRINT"LISTED FOR YOU TEN AT A TIME. OTHER"
  100. 1590 PRINT"INFORMATION REQUESTED FROM YOU WILL BE"
  101. 1600 PRINT"INDICATED BY A BLINKING BAR. PRESS THE"
  102. 1620 PRINT"FUNCTION KEYS TO OBTAIN DIFFERENT GROUPS";
  103. 1630 PRINT"OF CODES. SHOULD YOU WISH AN ENTRY NOT"
  104. 1660 PRINT"BE STORED TO A FILE, ENTER CATEGORY 00."
  105. 1663 PRINT"IF YOU WISH TO TERMINATE THE SESSION"
  106. 1665 PRINT"BEFORE CATALOGING ALL ENTRIES, ENTER"
  107. 1667 PRINT"CATAGORY 00 FOR THE REMAINING ENTRIES,"
  108. 1670 PRINT"FILE TO DISK, THEN LATER RELOAD THAT"
  109. 1673 PRINT"SAME SOURCE DISK AND ENTER CATEGORY 00"
  110. 1675 PRINT"FOR ALL ENTRIES CATALOGED EARLIER."
  111. 1680 PRINT"   PRESS ANY KEY."
  112. 1690 GETZZ$:IFZZ$=""THEN1690
  113. 1720 PRINT"[147]"TAB(6)"[158]***  ADD TO / CREATE FILES [146] ***"
  114. 1810 PRINT""TAB(13)"READ SOURCE DISK"
  115. 1840 PRINT""TAB(12)"EXIT THIS FUNCTION"
  116. 1870 PRINT""TAB(12)"[158]ENTER CHOICE (R/E)"
  117. 1880 GETZZ$:IFZZ$=""THEN1880
  118. 1890 IFZZ$="E"THENZZ$="":GOTO750
  119. 1900 IFZZ$<>"R"THEN1880
  120. 1930 PRINT""TAB(12)"READY SOURCE DISK"
  121. 1935 PRINT""TAB(15)"HIT ANY KEY"
  122. 1940 GETZZ$:IFZZ$=""THEN1940
  123. 1950 ZZ$="":CT=0:REM FILE ENTRY COUNT
  124. 1960 CT=0:OPEN3,8,0,"$0":GET#3,D1$,D2$
  125. 1980 GET#3,D1$,D2$,D1$,D2$
  126. 2010 PB$(CT)=RIGHT$("00"+MID$(STR$(ASC(D1$+CHR$(0))+256*ASC(D2$+CHR$(0))),2),3)
  127. 2050 GET#3,D2$:IFD2$=CHR$(34)THEN2080
  128. 2060 IFST=0THEN2050
  129. 2070 GOTO2220
  130. 2080 GET#3,D2$:IFD2$<>CHR$(34)THEND3$=D3$+D2$:GOTO2080
  131. 2100 PN$(CT)=D3$:D3$=""
  132. 2120 GET#3,D1$:IFD1$=" "THEN2120
  133. 2140 GET#3,D2$:IFCT=0THENID$=D1$+D2$
  134. 2160 GET#3,D2$:IFD2$<>""THEN2160
  135. 2180 CT=CT+1
  136. 2190 GOTO1980
  137. 2220 CLOSE3:CT=CT-1
  138. 2240 PRINT"[147]"TAB(8)" CATEGORY:                 ":A=10:GOSUB12300
  139. 3160 PRINT:PRINT"[176][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][174][157][148][195]"
  140. 3260 FORZZ=1TO5:PRINT"[194]"TAB(38)"[194][157][148] ":NEXTZZ
  141. 3340 PRINT"[173][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][189][157][148][195]"
  142. 3440 CU=1:CW=1:CV=1
  143. 3470 PRINT"";
  144. 3500 PRINT"[155]"PN$(CU)TAB(18)PB$(CU)TAB(22)ID$
  145. 3570 IFCU=CTTHEN3610
  146. 3580 IFCU/10=INT(CU/10)THEN3610
  147. 3590 CU=CU+1
  148. 3600 GOTO3500
  149. 3610 CU=CU+1
  150. 3630 PRINT"";:FORZZ=1TOCW:PRINT"";:NEXT:PRINT"[158]"PN$(CV):ZZ$="[133]"
  151. 3712 PRINT""TAB(19)"[154]               "
  152. 3720 POKEXREG,17:POKEYREG,0:SYSPLOT
  153. 3760 F=ASC(ZZ$)
  154. 3770 FORZZ=1+FN CAT(F)TO5+FN CAT(F)
  155. 3800 PRINT"[154]"RIGHT$("0"+RIGHT$(STR$(ZZ),LEN(STR$(ZZ))-1),2)"."M$(ZZ)" "TAB(20);
  156. 3810 PRINTRIGHT$("0"+RIGHT$(STR$(ZZ+5),LEN(STR$(ZZ+5))-1),2)"."M$(ZZ+5)" "
  157. 3890 NEXT ZZ
  158. 3950 POKEXREG,0:POKEYREG,19:SYSPLOT:AR=2:AZ=1:ZZ$="":GOSUB30000
  159. 3960 IFZZ$>="[133]"ANDZZ$<="[140]"THEN3720
  160. 3970 IFVAL(ZZ$)<0ORVAL(ZZ$)>80ORZZ$<"00"ORZZ$>"80"THEN3950
  161. 4050 PC$(CV)=ZZ$
  162. 4060 AZ=0:IFZZ$<>"00"THEN4070
  163. 4063 PRINT"";:FORZZ=1TOCW:PRINT"";:NEXT
  164. 4065 PRINT"                     ":GOTO5630
  165. 4070 PRINT""TAB(19)"[154]";:ZY=VAL(PC$(CV)):PRINTM$(ZY)
  166. 4092 ZY=ZY-1:ZZ=INT(ZY/8):ZX=ZZ*8:ZY=ZY-ZX:M%(ZZ)=M%(ZZ)OR2^ZY
  167. 4200 POKEXREG,17:POKEYREG,0:SYSPLOT
  168. 4260 PRINT"[154]XX=NO DEVICES      02=MODEM/USER PORT "
  169. 4300 PRINT"08=SINGLE DRIVE[174]   D8=DUAL DISK DRIVE "
  170. 4340 PRINT"  OR DUAL DRIVE[189]   89=TWO DISK DRIVES "
  171. 4380 PRINT"04=PRINTER         00=JOYSTICKS,ETC.  "
  172. 4420 PRINT"01=CASSETTE                           "
  173. 4440 POKEXREG,3+CW:POKEYREG,25:SYSPLOT
  174. 4450 AR=4:ZZ$="":GOSUB30000
  175. 4490 PE$(CV)=ZZ$
  176. 4500 POKEXREG,3+CW:POKEYREG,25:SYSPLOT:PRINTPE$(CV)
  177. 4680 POKEXREG,17:POKEYREG,0:SYSPLOT
  178. 4740 PRINT"[154]V+0    V+3    V+8    V16    V24    V32"
  179. 4760 PRINT"C64    AMG    C16    C+4    128    LCD"
  180. 4800 PRINT"PET    F40    CBM    SUP    BUS    HYP"
  181. 4810 PRINT"                                      "
  182. 4820 PRINT"                                      "
  183. 4920 POKEXREG,3+CW:POKEYREG,30:SYSPLOT
  184. 4930 AR=3:ZZ$="":GOSUB30000
  185. 4960 PM$(CV)=ZZ$
  186. 4970 POKEXREG,3+CW:POKEYREG,30:SYSPLOT:PRINTPM$(CV)
  187. 5150 POKEXREG,17:POKEYREG,0:SYSPLOT
  188. 5210 PRINT"[154]ENTER YOUR BEST GUESS IF MACHINE      "
  189. 5250 PRINT"CODE. 'BASIC' IF RELOCATABLE, @DATA   "
  190. 5260 PRINT"FOR FILES CALLED BY MAIN PROGRAMS.    "
  191. 5270 PRINT"                                      "
  192. 5280 PRINT"                                      "
  193. 5380 POKEXREG,3+CW:POKEYREG,34:SYSPLOT
  194. 5400 AR=5:ZZ$="":GOSUB30000
  195. 5450 PS$(CV)=ZZ$
  196. 5460 POKEXREG,3+CW:POKEYREG,34:SYSPLOT:PRINTPS$(CV)
  197. 5540 POKEXREG,3+CW:POKEYREG,0:SYSPLOT:PRINT"[151]"PN$(CV)
  198. 5630 IFCV=CTTHEN5680
  199. 5640 IFCV=CU-1THENQQ=10:GOSUB6090:GOTO6250
  200. 5650 CV=CV+1:CW=CW+1:GOTO3630
  201. 5680 PRINT"[147]"TAB(8)"[158]*** READY FILES DISK ***":PRINT""TAB(14)"HIT A KEY"
  202. 5685 GETZZ$:IFZZ$=""THEN5685
  203. 5686 PRINTTAB(12)"NOW SAVING FILES"
  204. 5689 FORZZ=0TO8:FORZX=0TO7
  205. 5700 IF(M%(ZZ)AND2^ZX)=0 THEN 5930
  206. 5710 ZW=ZZ*8+ZX+1:OPEN8,8,8,"0:^"+M$(ZW)+",S,R":INPUT#15,E:IFE=0THEN5780
  207. 5750 CLOSE8:OPEN8,8,8,"0:^"+M$(ZW)+",S,W":GOTO5800
  208. 5780 CLOSE8:OPEN8,8,8,"0:^"+M$(ZW)+",S,A"
  209. 5800 ZW$=RIGHT$("0"+RIGHT$(STR$(ZW),LEN(STR$(ZW))-1),2)
  210. 5830 FOR ZY=1 TO CT:IFPC$(ZY)<>ZW$THEN5910
  211. 5850 PRINT#8,PN$(ZY)CHR$(13)PB$(ZY)CHR$(13)ID$CHR$(13)PE$(ZY)CHR$(13)PM$(ZY)CHR$(13)PS$(ZY)
  212. 5910 NEXT ZY:CLOSE8
  213. 5930 NEXT ZX:NEXTZZ:GOTO750
  214. 6090 PRINT"";:FORZZ=1TOQQ:PRINT"                                 "
  215. 6100 NEXTZZ:RETURN
  216. 6250 CW=1:CV=CV+1:GOTO3470
  217. 6255 IFFL=0THEN6290
  218. 6260 PRINT"[147]"TAB(8)"[158]***  INSTRUCTIONS [146] ***"
  219. 6265 PRINT"[155]FROM THE LIST CHOOSE YOUR CATAEGORY."
  220. 6270 PRINT"PRESSING F1 WILL ALTERNATE THE TWO"
  221. 6275 PRINT"GROUPS OF CATEGORIES. THE ENTRIES WILL"
  222. 6280 PRINT"BE DISPLAYED FORTY AT A TIME."
  223. 6285 PRINT"   HIT A KEY"
  224. 6287 GETD1$:IFD1$=""THEN6287
  225. 6290 GOSUB6300:GOTO6710
  226. 6300 VV=1
  227. 6310 PRINT"[147]"TAB(5)"[158]CATEGORIES AND CODES ARE:":FORZZ=VVTOVV+19:ZW=ZZ+20
  228. 6350 ZZ$=RIGHT$("0"+RIGHT$(STR$(ZZ),LEN(STR$(ZZ))-1),2)
  229. 6370 ZW$=RIGHT$("0"+RIGHT$(STR$(ZW),LEN(STR$(ZW))-1),2)
  230. 6400 PRINT""ZZ$".[158]"M$(ZZ)""ZW$".[158]"M$(ZW):NEXT
  231. 6530 PRINT""TAB(8)" WHICH CATEGORY ? [146]"
  232. 6590 AZ=1:AR=2:ZZ$="":GOSUB30000
  233. 6600 IFZZ$="[133]"THENVV=42-VV:GOTO6310
  234. 6680 ZW=VAL(ZZ$):IFZW<1ORZW>80THENPRINT"[157][157]";:GOTO6590
  235. 6690 AZ=0:RETURN
  236. 6710 PRINT"[147]"TAB(8)" CATEGORY: [158]"M$(ZW):A=20:L=0:GOSUB12300
  237. 7620 PRINT"";:OPEN8,8,8,"0:^"+M$(ZW)+",S,R":SR=ST:INPUT#15,E:IFE=0THEN7965
  238. 7750 PRINT"[154]NO FILE"
  239. 7770 CLOSE8
  240. 7810 PRINT"[150] ANOTHER TOPIC? [146]":PRINT" (Y OR N) [146]"
  241. 7910 GETD1$:IFD1$=""THEN7910
  242. 7920 IFD1$="Y"THEN6290
  243. 7930 IFD1$="N"THEN750
  244. 7940 GOTO7910
  245. 7965 IFSRTHEN7770
  246. 7970 INPUT#8,A$,B$,C$,D$,E$,F$:SR=ST:A$=LEFT$(A$+"                ",16)
  247. 7990 PRINT"[158]"A$""B$""C$""D$""E$""F$:L=L+1:IFL<17THEN7965
  248. 8030 PRINT"[150]PRESS SPACE [146]":PRINT"TO CONTINUE.":PRINT"PRESS @ [146]TO EXIT."
  249. 8180 GETD1$:IFD1$=""THEN8180
  250. 8190 IFD1$=" "THENQQ=20:GOSUB6090:PRINT"";:L=0:GOTO7965
  251. 8200 IFD1$="@"THENCLOSE8:QQ=20:GOSUB6090:PRINT"";:GOTO7810
  252. 8210 GOTO8180
  253. 8220 IFFL=0THEN8340
  254. 8230 PRINT"[147]"TAB(8)"[158]***  INSTRUCTIONS [146] ***"
  255. 8240 PRINT"[155]AFTER SELECTING A CATEGORY, YOU ARE"
  256. 8250 PRINT"ASKED TO ALIGN THE PAPER TO THE TOP OF"
  257. 8260 PRINT"THE FORM. WHEN READY, HIT ANY KEY. ALL"
  258. 8280 PRINT"ENTRIES WILL BE SENT TO DEVICE 4,"
  259. 8290 PRINT"FORTY AT A TIME."
  260. 8295 PRINT"THESE PRINT ROUTINES WERE DEVELOPED FOR"
  261. 8300 PRINT"A CARDCO+G AND ANY EPSON COMPATIBLE"
  262. 8305 PRINT"PRINTER. GOOD LUCK ON OTHER PRINTERS.":PRINT"   HIT A KEY"
  263. 8330 GETD1$:IFD1$=""THEN 8330
  264. 8340 GOSUB6300
  265. 8770 OPEN8,8,8,"0:^"+M$(ZW)+",S,R":SR=ST:INPUT#15,E:IFE=0THEN8810
  266. 8801 CLOSE8:PRINT"[147]"TAB(11)"ERROR MESSAGE "E:FORX=1TO1000:NEXTX:GOTO750
  267. 8810 PRINT"[147]"TAB(8)M$(ZW):PRINT""TAB(6)"ALIGN PAPER TO TOP OF FORM"
  268. 8880 PRINT"         HIT A KEY WHEN READY"
  269. 8890 GETD1$:IFD1$=""THEN8890
  270. 8900 OPEN4,4,5:PRINT#4,CHR$(27)CHR$(65)CHR$(7)CHR$(13);:CLOSE4
  271. 8905 OPEN4,4,6:OPEN5,4,0:Y=1
  272. 8920 FORX=1TO5:PRINT#4:NEXT:PRINT#4,SPC(22);:D2$="":ZZ$=M$(ZW):GOSUB40000
  273. 8954 PRINT#4,D2$;:PRINT#4,SPC(12)"[208][193][199][197]"Y:PRINT#4,SPC(5)CHR$(176);
  274. 8980 FORX=1TO18:PRINT#5,CHR$(99);:NEXTX:PRINT#4,CHR$(178);
  275. 8990 FORX=1TO5:PRINT#5,CHR$(99);:NEXTX:PRINT#4,CHR$(178);
  276. 9000 FORX=1TO4:PRINT#5,CHR$(99);:NEXTX:PRINT#4,CHR$(178);
  277. 9010 FORX=1TO6:PRINT#5,CHR$(99);:NEXTX:PRINT#4,CHR$(178);
  278. 9020 FORX=1TO5:PRINT#5,CHR$(99);:NEXTX:PRINT#4,CHR$(178);
  279. 9030 FORX=1TO7:PRINT#5,CHR$(99);:NEXTX
  280. 9060 PRINT#4,CHR$(174):PRINT#4,SPC(5);:PRINT#5,CHR$(98);
  281. 9072 PRINT#4,"   [208][210][207][199][210][193][205] [206][193][205][197]   ";:PRINT#5,CHR$(98);
  282. 9075 PRINT#4," [194][204][203] ";:PRINT#5,CHR$(98);:PRINT#4," [201][196] ";:PRINT#5,CHR$(98);
  283. 9077 PRINT#4," [197][209][213][208] ";:PRINT#5,CHR$(98);:PRINT#4," [205][196][204] ";:PRINT#5,CHR$(98);
  284. 9080 PRINT#4," [204][207][193][196]@ ";:PRINT#5,CHR$(98):PRINT#4,SPC(5)CHR$(171);
  285. 9100 FORX=1TO18:PRINT#5,CHR$(99);:NEXTX:PRINT#4,CHR$(123);
  286. 9110 FORX=1TO5:PRINT#5,CHR$(99);:NEXTX:PRINT#4,CHR$(123);
  287. 9120 FORX=1TO4:PRINT#5,CHR$(99);:NEXTX:PRINT#4,CHR$(123);
  288. 9130 FORX=1TO6:PRINT#5,CHR$(99);:NEXTX:PRINT#4,CHR$(123);
  289. 9133 FORX=1TO5:PRINT#5,CHR$(99);:NEXTX:PRINT#4,CHR$(123);
  290. 9135 FORX=1TO7:PRINT#5,CHR$(99);:NEXTX
  291. 9140 PRINT#4,CHR$(179):REM CMDR W
  292. 9150 ZX=0
  293. 9160 ZX=ZX+1:IFSR=0 THEN 9170
  294. 9161 PRINT#4,SPC(5);:PRINT#5,CHR$(98);
  295. 9162 PRINT#4," [197][206][196] [207][198] [198][201][204][197]      ";:PRINT#5,CHR$(98);
  296. 9163 PRINT#4,"     ";:PRINT#5,CHR$(98);:PRINT#4,"    ";:PRINT#5,CHR$(98);
  297. 9164 PRINT#4,"      ";:PRINT#5,CHR$(98);:PRINT#4,"     ";:PRINT#5,CHR$(98);
  298. 9165 PRINT#4,"       ";:PRINT#5,CHR$(98)
  299. 9169 GOTO 9330
  300. 9170 INPUT#8,PN$,PB$,PI$,PE$,PM$,PS$
  301. 9180 SR=ST
  302. 9185 PRINT#4,SPC(5)
  303. 9190 PRINT#5,CHR$(98);
  304. 9200 D2$="":ZZ$=PN$:GOSUB40000:PRINT#4,LEFT$(" "+D2$+"                 ",18);
  305. 9210 PRINT#5,CHR$(98);
  306. 9220 D2$="":ZZ$=PB$:GOSUB40000:PRINT#4," "D2$" ";:PRINT#5,CHR$(98);
  307. 9240 D2$="":ZZ$=PI$:GOSUB40000:PRINT#4," "D2$" ";:PRINT#5,CHR$(98);
  308. 9260 D2$="":ZZ$=PE$:GOSUB40000:PRINT#4," "D2$" ";:PRINT#5,CHR$(98);
  309. 9280 D2$="":ZZ$=PM$:GOSUB40000:PRINT#4," "D2$" ";:PRINT#5,CHR$(98);
  310. 9300 D2$="":ZZ$=PS$:GOSUB40000:PRINT#4," "D2$" ";:PRINT#5,CHR$(98)
  311. 9310 IF ZX>39 THEN 9330
  312. 9311 PRINT#4,SPC(5);:PRINT#5,CHR$(98);:PRINT#4,"                  ";:PRINT#5,CHR$(98);
  313. 9312 PRINT#4,"     ";:PRINT#5,CHR$(98);:PRINT#4,"    ";:PRINT#5,CHR$(98);
  314. 9313 PRINT#4,"      ";:PRINT#5,CHR$(98);:PRINT#4,"     ";:PRINT#5,CHR$(98);
  315. 9314 PRINT#4,"       ";:PRINT#5,CHR$(98):GOTO9160
  316. 9330 PRINT#4,SPC(5);
  317. 9340 PRINT#4,CHR$(173);:REM CMDR Z
  318. 9350 FORX=1TO18:PRINT#5,CHR$(99);:NEXTX:PRINT#4,CHR$(177);
  319. 9360 FORX=1TO5:PRINT#5,CHR$(99);:NEXTX:PRINT#4,CHR$(177);
  320. 9370 FORX=1TO4:PRINT#5,CHR$(99);:NEXTX:PRINT#4,CHR$(177);
  321. 9380 FORX=1TO6:PRINT#5,CHR$(99);:NEXTX:PRINT#4,CHR$(177);
  322. 9383 FORX=1TO5:PRINT#5,CHR$(99);:NEXTX:PRINT#4,CHR$(177);
  323. 9385 FORX=1TO7:PRINT#5,CHR$(99);:NEXTX
  324. 9390 PRINT#4,CHR$(189):REM CMDR X
  325. 9400 PRINT#4,CHR$(12)
  326. 9470 Y=Y+1
  327. 9480 IF SR=0 THEN 8920
  328. 9485 CLOSE8
  329. 9490 CLOSE4
  330. 9500 GOTO750
  331. 12000 CLOSE4:CLOSE8:CLOSE15
  332. 12001 OPEN15,8,15:CLOSE15
  333. 12005 IF FL=0 THEN12200
  334. 12010 PRINT"[147]"TAB(7)"[158]***  ENDING COMMENTS [146] ***"
  335. 12050 PRINT"[155]LIBRARY INDEX ENTRIES ARE SORTED IN"
  336. 12060 PRINT"CHRONOLOGICAL ORDER. SHOULD YOU WISH"
  337. 12080 PRINT"THEM[160]SORTED DIFFERENTLY, 'FILE SORT' BY"
  338. 12090 PRINT"J.BUTTERFIELD WILL HELP (TPUG TA.C)."
  339. 12110 PRINT"AS ALWAYS, MAKE AN ARCHIVAL COPY OF THE"
  340. 12120 PRINT"FILES AS SOON AS POSSIBLE.":PRINT"   HIT ANY KEY"
  341. 12170 GETZZ$:IFZZ$="" THEN 12170
  342. 12200 PRINT"[147]"TAB(16)"[158]GOODBYE!":END
  343. 12300 PRINT"[176][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][178][195][195][195][178][195][195][178][195][195][195][195][178][195][195][195][178][195][195][195][195][174][157][148][195]"
  344. 12470 PRINT"[194]  PROGRAM NAME  [194]BLK[194]ID[194]EQUP[194]MDL[194]LOAD[194][157][148]@"
  345. 12630 PRINT"[171][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][219][195][195][195][219][195][195][219][195][195][195][195][219][195][195][195][219][195][195][195][195][179][157][148][195]"
  346. 12800 FORZZ=1TOA
  347. 12810 PRINT"[194]"TAB(17)"[194]"TAB(21)"[194]"TAB(24)"[194]"TAB(29)"[194]"TAB(33)"[194]"TAB(38)"[194][157][148] "
  348. 12970 NEXT ZZ
  349. 12980 PRINT"[173][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][177][195][195][195][177][195][195][177][195][195][195][195][177][195][195][195][177][195][195][195][195][189][157][148][195]";:RETURN
  350. 30000 FORQQ=1TOAR:PRINT" ";:NEXT:FORQQ=1TOAR:PRINT"[157]";:NEXT
  351. 30003 PRINT"[175][157]";:FOR QQ=1TO100:GETZ$:IFZ$<>""THENQQ=500:NEXT:GOTO30010
  352. 30004 NEXT
  353. 30007 PRINT" [157]";:FOR QQ=1TO100:GETZ$:IFZ$<>""THENQQ=500:NEXT:GOTO30010
  354. 30008 NEXT:GOTO30003
  355. 30010 IFZ$=CHR$(20)THENIFAT>0THENPRINT" [157][157] [157]";:AT=AT-1:ZZ$=LEFT$(ZZ$,AT):GOTO30003
  356. 30011 IFAZ=1THENIFZ$>="[133]"ANDZ$<="[140]"THENAT=0:PRINT" [157]";:ZZ$=Z$:RETURN
  357. 30012 IFZ$=CHR$(20)THENZ$="":GOTO30003
  358. 30013 IFZ$=CHR$(13)THENZ$="":GOTO30003
  359. 30014 IFZ$<CHR$(32)ORZ$>CHR$(90)THENZ$="":GOTO30003
  360. 30015 PRINTZ$;:ZZ$=ZZ$+Z$:AT=AT+1
  361. 30020 IFAT<ARTHEN30003
  362. 30025 GETZ$:IFZ$=""THEN30025
  363. 30030 IFZ$=CHR$(20)THENPRINT"[157] [157]";:AT=AT-1:ZZ$=LEFT$(ZZ$,AT):GOTO30003
  364. 30040 IFZ$<>CHR$(13)THEN30025
  365. 30045 AT=0:RETURN
  366. 40000 FORZZ=1TOLEN(ZZ$):ZY=ASC(MID$(ZZ$,ZZ,1)):IFZY>63ANDZY<96THENZY=ZY+32
  367. 40010 D2$=D2$+CHR$(ZY):NEXTZZ:RETURN
  368.